init with {: System.out.println("Calculatrice avec priorité");  prompt(); :}

parser code {:
  static void prompt() { System.out.print("> "); }
:}

terminal NL, LPAR, RPAR, COMMA, FMIN, FMAX;
terminal PLUS, MOINS, MULT, DIV, MOD;
terminal Integer ENTIER;

nonterminal lignes, ligne;
nonterminal Integer expr, args;

precedence left PLUS,MOINS;
precedence left MULT,DIV,MOD;

lignes ::= /* vide */   {: :}
       |   lignes ligne {: prompt(); :}  NL
;
ligne  ::= expr:e       {: System.out.println(" = " + e); :}
       |   /* vide*/    {: :}
       |   error        {: /* msg ? */ :}
;
expr   ::= ENTIER:e              {: RESULT = e; :}
       |   LPAR expr:e RPAR      {: RESULT = e; :}
       |   expr:e1 PLUS expr:e2  {: RESULT = e1 + e2; :}
       |   expr:e1 MOINS expr:e2 {: RESULT = e1 - e2; :}
       |   expr:e1 MULT expr:e2  {: RESULT = e1 * e2; :}
       |   expr:e1 DIV expr:e2   {: RESULT = e1 / e2; :}
       |   expr:e1 MOD expr:e2   {: RESULT = e1 % e2; :}
       |   FMIN LPAR expr:e1 COMMA expr:e2 RPAR
                                 {: RESULT = (e1>e2)?e2:e1; :} 
       |   FMAX LPAR args:e RPAR {: RESULT = e; :}
;
args   ::= expr:e                {: RESULT = e; :}
       |   args:e1 COMMA expr:e2 {: RESULT = (e1>e2)?e1:e2; :}
;